tulrich.com
☰ Menu+  instagram  tuffy  ringing ear 

geekstuff | gameswf | Textweb | Chunked LOD | dumbuild

Cheat sheets: CVS | cygwin | Debian | Emacs | MythTV

Plotting Burndown Charts

Burndown Charts are nice for getting a feel for how your project is going. (See here for more info on Burndown etc.)

I was using Excel for a while, but the output looks like crap, and it's a pain to generate a .png version.

I finally (after much grunting & sweating) came up with a gnuplot script to draw OK-looking burndown charts, for web (.png) and printing (.ps). The output looks like:


The script should be self explanatory, just hack it up to make it work for your data:

#!/usr/local/bin/gnuplot

# gnuplot script to generate project burndown chart

# For gnuplot version 4+!  Doesn't work with 3.x

set xdata time
set timefmt "%m/%d/%Y"
set xrange ["5/1/2006":"9/27/2006"]
set xzeroaxis
set title "BURNDOWN"
set xtics rotate by 0 ("5/5/2006","5/18/2006","6/1/2006","6/15/2006", \
                       "6/29/2006","7/14/2006","7/27/2006","8/10/2006",\
		       "8/24/2006","9/7/2006","9/21/2006")
set format x "%m/%d"
set grid ytics

set style fill solid 1.0 noborder
set boxwidth 0.7 relative
unset key

# burndown_data.dat should have format like:
#
# # Measurement date    points-top    points-bottom
# mm/dd/yyyy            ###           ###
#

# At the end of an iteration, you compute points-top by taking
# points-top-last, and subtracting all the points for the stories you
# did that iteration.
#
# You compute points-bottom by taking points-top, and subtracting the
# points for all the TODO stories.

# For interactive viewing.
# plot 'data_dir/burndown_data.dat' using 1:2:2:3:3 with candlesticks

# For image & print output.
set terminal png font "/usr/share/fonts/msttcorefonts/arial.ttf" 10 size 800,600
set output "output_dir/burndown.png"
plot 'data_dir/burndown_data.dat' using 1:2:2:3:3 with candlesticks

set terminal postscript landscape color
set output "output_dir/burndown.ps"
replot
tu@tulrich.com |